home *** CD-ROM | disk | FTP | other *** search
/ The Game Master (3rd Edition) / The Game Master 3rd edition.iso / files / gamecard / condo / cia.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1986-03-06  |  13.7 KB  |  258 lines

  1. 1  ' CIA (12/05/84) rev.9/21/85 07/06/86 cfb
  2. 10  CLEAR 3000:CLS:SEED=VAL(MID$(TIME$,7,2)):RANDOMIZE(SEED):DEFINT A-Z:GOTO 40
  3. 20  Z9=0:FOR R=1 TO 50:IF V1$=N$(R) AND (N(R)=LO OR N(R)=-1) THEN Z9=1:RETURN
  4. 30  NEXT:PRINT"I DON'T SEE THAT HERE.":Z9=2:RETURN
  5. 40  PRINT "          C.I.A  MISSION"
  6. 42  PRINT
  7. 45  PRINT"           revised 9/21/85":PRINT
  8. 50  DIM N1$(50),N$(50),N(50),V$(18),LO(30,4),LO$(30):FL=1:DR=0:DG=-1:T=0:EL=0:BU=0:DO=0:CA=0:BA=0:TE=0:GL=0
  9. 60  PA=0:RO=0:FOR R=1 TO 5:R1=RND(9):CO$=CO$+STR$(R1):NEXT:LO=1:A9$=">"+STRING$(62,"-")+"<"
  10. 70  R=LEN(CO$):CO$=RIGHT$(CO$,R-1)
  11. 80  FOR R=1 TO 50:READ N1$(R),N$(R),N(R):NEXT
  12. 90  FOR R=1 TO 30:READ LO$(R),LO(R,1),LO(R,2),LO(R,3),LO(R,4):NEXT
  13. 100  FOR R=1 TO 18:READ V$(R):NEXT
  14. 110  REM
  15. 120  PRINT"WE ARE ";LO$(LO);"."
  16. 130  FOR R=1 TO 46:IF N(R)=LO THEN PRINT"I CAN SEE ";N1$(R);"."
  17. 140  NEXT:B=0:FOR R=1 TO 4:IF LO(LO,R)>0 THEN B=1
  18. 150  NEXT:IF B=0 THEN 200
  19. 160  PRINT"WE COULD EASILY GO: ";:IF LO(LO,1)>0 THEN PRINT"NORTH  ";
  20. 170  IF LO(LO,2)>0 THEN PRINT"SOUTH  ";
  21. 180  IF LO(LO,3)>0 THEN PRINT"EAST  ";
  22. 190  IF LO(LO,4)>0 THEN PRINT"WEST  ";
  23. 200  PRINT:PRINT A9$
  24. 210  T=T+1:IF DG>0 THEN DG=DG-1
  25. 220  IF T=1 THEN INPUT "ENTER YOUR NAME PARTNER";A$:GOSUB 30000:NA$=A$:A$=""
  26. 230  GOTO 1760
  27. 240  N=0:FOR R=1 TO 46:IF N(R)=-1 THEN N=N+1
  28. 250  NEXT
  29. 260  PRINT:INPUT"WHAT DO YOU THINK WE SHOULD DO";A$
  30. 265  GOSUB 30000
  31. 270  GOSUB 1890:V$=LEFT$(A$,3):GOSUB 1950:FOR R=1 TO 18:IF V$=V$(R) THEN 300 ELSE NEXT
  32. 280  IF V$="ORD" THEN 2210
  33. 290  PRINT"I DON'T KNOW HOW TO DO THAT.":GOTO 260
  34. 300  IF V$="QUI" THEN 1650
  35. 310  V=R:FOR R=1 TO LEN(A$):IF MID$(A$,R,1)=" " THEN 360 ELSE NEXT
  36. 320  IF V$="LOO" THEN 110
  37. 330  IF V$="BON" THEN 1670
  38. 340  IF V$="INV" THEN 1690
  39. 350  PRINT"PLEASE USE 2 WORD COMMANDS SO I CAN UNDERSTAND YOU.":GOTO 260
  40. 360  V1$=MID$(A$,R+1,3):FOR R=1 TO 49:IF V1$=N$(R) THEN 390 ELSE NEXT
  41. 370  IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 390
  42. 380  PRINT"I DON'T KNOW WHAT IT IS YOU ARE TALKING ABOUT.":GOTO 260
  43. 390  ON V GOTO 400,530,620,680,800,840,1040,1140,1300,1320,1360,1450,1490,1540,1600,1650,1670,1690
  44. 400  IF V1$="NOR" AND LO(LO,1)>0 THEN LO=LO(LO,1):GOTO 110
  45. 410  IF V1$="SOU" AND LO(LO,2)>0 THEN LO=LO(LO,2):GOTO 110
  46. 420  IF V1$="EAS" AND LO(LO,3)>0 THEN LO=LO(LO,3):GOTO 110
  47. 430  IF V1$="WES" AND LO(LO,4)>0 THEN LO=LO(LO,4):GOTO 110
  48. 440  IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 520
  49. 450  GOSUB 20:IF Z9=2 THEN 210
  50. 460  IF R=8 THEN LO=5:GOTO 110
  51. 470  IF R=37 AND RO=1 AND LO=20 THEN LO=21:GOTO 110
  52. 480  IF R=10 THEN LO=11:GOTO 110
  53. 490  IF R=14 THEN LO=13:GOTO 110
  54. 500  IF R=33 THEN LO=3:GOTO 110
  55. 510  IF R=34 AND DO=1 THEN LO=9:GOTO 110
  56. 520  PRINT"I CAN'T GO THAT WAY AT THE MOMENT.":GOTO 210
  57. 530  GOSUB 20:IF Z9=2 THEN 210
  58. 540  IF R=2 OR R=3 OR R=4 OR R=6 OR R=15 OR R=16 OR R=20 OR R=21 OR R=22 OR R=23 OR R=25 OR R=26 OR R=27 OR R=28 OR R=30 OR R=31 OR R=37 OR R=39 OR R=40 OR R=42 OR R=44 OR R=45 OR R=46 THEN 560
  59. 550  PRINT"I CAN'T CARRY THAT!":GOTO 210
  60. 560  IF N(R)=-1 THEN PRINT"I ALREADY HAVE IT.":GOTO 210
  61. 570  IF N>=5 THEN PRINT"I CAN'T CARRY ANYMORE.":GOTO 210
  62. 580  PRINT"O.K.":N(R)=-1
  63. 590  IF V1$="PAI" AND PA=0 THEN PRINT"SOMETHING FELL FROM THE FRAME!":N(31)=LO:PA=1
  64. 600  IF V1$="TEL" THEN TE=0
  65. 610  GOTO 210
  66. 620  FOR R=1 TO 46:IF V1$=N$(R) AND N(R)=-1 THEN 640 ELSE NEXT
  67. 630  PRINT"I DON'T SEEM TO BE CARRYING IT.":GOTO 210
  68. 640  IF R=30 THEN PRINT"I DROPPED THE CUP BUT IT BROKE INTO SMALL PIECES.":PRINT"THE COFFEE SOAKED INTO THE GROUND.":N(30)=0:DR=0:GOTO 210
  69. 650  IF R=45 THEN GL=0
  70. 660  IF R=31 AND N(30)=-1 THEN PRINT"O.K. I DROPPED IT.":PRINT"BUT IT FELL IN THE COFFEE!":N(31)=0:DR=1:GOTO 210
  71. 670  PRINT"O.K. I DROPPED IT.":N(R)=LO:GOTO 210
  72. 680  IF V1$="BUT" AND LO=3 AND DO=0 THEN PRINT"THE DOORS OPEN WITH A WHOOSH!":DO=1:GOTO 210
  73. 690  IF N(46)=-1 AND V1$="BUT" THEN PRINT"I PUSH THE BUTTON ON THE BOX AND":GOTO 770
  74. 700  GOSUB 20
  75. 710  IF Z9=2 THEN 210
  76. 720  IF R=17 AND GL<>1 THEN PRINT"THERE'S ELECTRICITY COURSING THRU THE SQUARE!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  77. 730  IF R=35 AND BU=0 THEN PRINT"THE BUTTON ON THE WALL GOES IN .....":PRINT"CLICK! SOMETHING SEEMS DIFFFERENT NOW.":BU=1:GOTO 210
  78. 740  IF R=47 AND FL<>1 THEN LO(9,1)=3:FL=1:GOTO 790
  79. 750  IF R=48 AND FL<>2 THEN LO(9,1)=8:FL=2:GOTO 790
  80. 760  IF R=49 AND FL<>3 THEN LO(9,1)=10:FL=3:GOTO 790
  81. 770  IF N(46)=-1 AND (LO=6 OR LO=29) THEN PRINT"THERE IS A BLINDING FLASH....":FOR R=1 TO 3000:NEXT:LO=1:FL=1:LO(9,1)=3:GOTO 110
  82. 780  PRINT"NOTHING HAPPENS.":GOTO 210
  83. 790  PRINT"THE DOORS CLOSE AND I FEEL AS IF THE ROOM IS MOVING.":PRINT"SUDDENLY THE DOORS OPEN AGAIN.":FOR R=1 TO 5000:NEXT:GOTO 110
  84. 800  GOSUB 20:IF Z9=2 THEN 210
  85. 810  IF R=18 AND GL<>1 THEN PRINT"THE LEVER HAS ELECTRICITY COURSING THRU IT!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  86. 820  IF R=18 AND EL=0 THEN PRINT"THE LEVER GOES ALL THE WAY UP AND CLICKS.":PRINT"SOMETHING SEEMS DIFFERENT NOW.":EL=1:GOTO 210
  87. 830  PRINT"NOTHING HAPPENS.":GOTO 210
  88. 840  REM
  89. 850  IF V1$="DRA" AND LO=5 THEN PRINT"IT LOOKS FRAGILE.":GOTO 210
  90. 860  GOSUB 20:IF Z9=2 THEN 210
  91. 870  IF R=1 AND BA<>1 THEN PRINT"THERE'S NO POWER FOR IT.":GOTO 210
  92. 880  IF R=1 AND TE<>1 THEN PRINT"THERE'S NO T.V. TO WATCH ON.":GOTO 210
  93. 890  IF R=6 THEN PRINT"IT LOOKS HEAVY.":GOTO 210
  94. 900  IF R=7 THEN PRINT"IT'S LOCKED.":GOTO 210
  95. 910  IF R=13 THEN PRINT"IT'S A VERY STRONG BAG.":GOTO 210
  96. 920  IF R=19 THEN PRINT"I CAN SEE A LOCKED DRAWER IN IT.":GOTO 210
  97. 930  IF R=22 OR R=27 THEN PRINT"THERE'S WRITING ON IT.":GOTO 210
  98. 940  IF R=34 AND DO=1 THEN PRINT"THE DOORS ARE OPEN.":GOTO 210
  99. 950  IF R=24 THEN PRINT"I CAN SEE A GLEAMING STONE IN IT.":GOTO 210
  100. 960  IF R=9 THEN PRINT"THERE IS A SMALL SLIT NEAR THE DOOR.":GOTO 210
  101. 970  IF R=34 THEN PRINT"THERE'S A BUTTON NEAR THE DOORS.":GOTO 210
  102. 980  IF R=41 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 210
  103. 990  IF R=41 THEN PRINT"I SEE A METAL PIT 1000'S OF FEET DEEP ON ONE MONITOR.":PRINT"ON THE OTHER SIDE OF THE PIT,I SEE A LARGE HOOK.":GOTO 210
  104. 1000  IF R=43 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 210
  105. 1010  IF R=43 THEN PRINT"I SEE A ROOM WITH A CASE ON A PEDESTAL IN IT.":GOTO 210
  106. 1020  IF R=44 THEN PRINT"I SEE A PICTURE OF A GRINNING JACKAL.":GOTO 210
  107. 1030  PRINT"I SEE NOTHING OF INTEREST.":GOTO 210
  108. 1040  GOSUB 20:IF Z9=2 THEN 210
  109. 1050  IF R<>3 AND R<>2 AND R<>4 AND R<>28 THEN PRINT"I CAN'T INSERT THAT!":GOTO 210
  110. 1060  INPUT"TELL ME, IN ONE WORD, INTO WHAT";A3$:A3$=LEFT$(A3$,3)
  111. 1070  R1=R:V1$=A3$:GOSUB 20:IF Z9=2 THEN 210
  112. 1080  IF R1=3 AND R=1 THEN PRINT"O.K.":BA=1:N(3)=0:BA=1:GOTO 210
  113. 1090  IF R1=4 AND R=50 AND DG<=0 THEN PRINT"THE GUARD WON'T LET ME!":GOTO 210
  114. 1100  IF R1=2 AND R=1 THEN PRINT"O.K. THE TAPE IS IN THE RECORDER.":N(2)=0:TA=1:GOTO 210
  115. 1110  IF R1=4 AND R=50 THEN PRINT"POP! A SECTION OF THE WALL OPENS.....":PRINT"REVEALING SOMETHING VERY INTERESTING.":N(4)=0:N(5)=LO:GOTO 210
  116. 1120  IF R1=28 AND R=29 THEN PRINT"POP! A CUP OF COFFEE COMES OUT OF THE MACHINE.":N(28)=0:N(30)=LO:GOTO 210
  117. 1130  PRINT"NOTHING HAPPENED.":GOTO 210
  118. 1140  REM
  119. 1150  IF V1$="DRA" AND LO=5 AND N(23)=0 THEN PRINT"IT'S STUCK.":GOTO 210
  120. 1160  GOSUB 20:IF Z9=2 THEN 210
  121. 1170  IF R=7 OR R=9 OR R=13 OR R=15 OR R=23 OR R=32 OR R=5 THEN 1190
  122. 1180  PRINT"I CAN'T OPEN THAT!":GOTO 210
  123. 1190  IF R=7 AND N(16)=-1 THEN PRINT"O.K. I OPENED THE DOOR.":N(7)=0:N(8)=4:GOTO 210
  124. 1200  IF R=9 THEN PRINT"I CAN'T. IT DOESN'T WORK.":GOTO 210
  125. 1210  IF R=13 AND N(16)=-1 THEN PRINT"O.K. THE CLOSET IS OPENED.":N(13)=0:N(14)=14:GOTO 210
  126. 1220  IF R=15 THEN PRINT"I CAN'T. IT'S TOO STRONG.":GOTO 210
  127. 1230  IF R=23 THEN PRINT"IT'S STUCK.":GOTO 210
  128. 1240  IF R=32 AND N(28)=0 AND N(4)=0 AND SC=1 THEN PRINT "I OPEN THE SCULPTURE.":PRINT"SOMETHING FALLS OUT.":N(28)=LO:N(4)=LO:GOTO 210
  129. 1250  IF R<>5 THEN 1290
  130. 1260  INPUT"WHAT'S THE COMBINATION";C$
  131. 1270  IF C$=CO$ THEN PRINT"THE DOOR IS SLOWLY OPENING.":N(5)=0:N(9)=0:N(10)=10:GOTO 210
  132. 1280  PRINT"YOU MUST HAVE THE WRONG COMBINATION OR YOU ARE NOT":PRINT"SAYING IT RIGHT.":GOTO 210
  133. 1290  PRINT"I CAN'T DO THAT......YET!":GOTO 210
  134. 1300  IF V1$="GLO" AND N(45)=-1 THEN PRINT"O.K. I'M NOW WEARING THE GLOVES.":GL=1:GOTO 210
  135. 1310  PRINT"I CAN'T WEAR THAT!":GOTO 210
  136. 1320  IF V1$<>"SIG" AND V1$<>"NOT" THEN PRINT"I CAN'T READ THAT.":GOTO 210
  137. 1330  GOSUB 20:IF Z9=2 THEN 210
  138. 1340  IF R=22 THEN PRINT"IT SAYS:":PRINT NA$;",":PRINT"  WE HAVE DISCOVERED ONE OF CHAOS'S SECRET WORDS.":PRINT"IT IS: BOND-007-. TO BE USED IN A -TASTEFUL- SITUATION.":GOTO 210
  139. 1350  IF R=27 THEN PRINT"IT SAYS: WATCH OUT! DANGEROUS!":GOTO 210
  140. 1360  IF V1$<>"REC" THEN PRINT"I CAN'T START THAT.":GOTO 210
  141. 1370  GOSUB 20:IF Z9=2 THEN 210
  142. 1380  IF BA<>1 OR TE<>1 OR TA<>1 THEN 1440
  143. 1390  PRINT"THE RECORDER STARTS UP AND PRESENTS A SHORT MESSAGE:"
  144. 1400  PRINT;NA$;","
  145. 1410  PRINT"WE HAVE UNCOVERED A NUMBER THAT MAY HELP YOU."
  146. 1420  PRINT"THAT NUMBER IS:";CO$;". PLEASE WATCH OUT FOR HIDDEN TRAPS."
  147. 1430  PRINT"ALSO, THERE IS SOMETHING IN THE SCULPTURE.":SC=1:GOTO 210
  148. 1440  PRINT"NOTHING HAPPENED.":GOTO 210
  149. 1450  IF V1$<>"DRA" THEN PRINT"I'M TRYING TO BREAK IT, BUT I CAN'T.":GOTO 210
  150. 1460  IF N(6)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  151. 1470  IF LO=5 THEN PRINT"IT'S HARD....BUT I GOT IT. TWO THINGS FELL OUT.":N(3)=LO:N(22)=LO:N(23)=LO:GOTO 210
  152. 1480  PRINT"NOTHING HAPPENS.":GOTO 210
  153. 1490  GOSUB 20:IF Z9=2 THEN 210
  154. 1500  IF R<>15 AND R<>24 THEN PRINT"I'M TRYING. IT DOESN'T WORK.":GOTO 210
  155. 1510  IF N(25)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  156. 1520  IF R=15 THEN PRINT"RIP! THE BAG GOES TO PIECES, AND SOMETHING FALLS OUT!":N(15)=0:N(2)=LO:GOTO 210
  157. 1530  IF R=24 THEN PRINT"I CUT THE CASE AND REACH IN TO PULL SOMETHING OUT.":N(26)=-1:GOTO 210
  158. 1540  IF V1$<>"ROP" THEN PRINT"I CAN'T THROW THAT.":GOTO 210
  159. 1550  IF N(37)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  160. 1560  INPUT"TELL ME,IN ONE WORD,AT WHAT";A3$:A3$=LEFT$(A3$,3)
  161. 1570  IF A3$<>"HOO" THEN PRINT"O.K. I THREW IT.":N(37)=LO:GOTO 210
  162. 1580  IF LO<>20 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  163. 1590  PRINT"I THREW THE ROPE AND IT SNAGGED ON THE HOOK.":RO=1:N(37)=LO:GOTO 210
  164. 1600  IF V1$<>"TEL" THEN PRINT"I CAN'T CONNECT THAT.":GOTO 210
  165. 1610  IF N(40)<>LO THEN PRINT"I DON'T SEE THE TELEVISION HERE.":GOTO 210
  166. 1620  IF TE=1 THEN PRINT"I DID THAT ALREADY.":GOTO 210
  167. 1630  IF LO<>2 THEN PRINT"I CAN'T DO THAT....YET!":GOTO 210
  168. 1640  PRINT"O.K. THE T.V. IS CONNECTED.":TE=1:GOTO 210
  169. 1650  PRINT"WHAT? YOU WOULD LEAVE ME HERE TO DIE ALONE?"
  170. 1660  PRINT"JUST FOR THAT, I'M GOING TO DESTROY THE GAME.":PRINT:PRINT:PRINT:PRINT"BOOOOOOOOOOOOM!":FOR R=1 TO 5000:NEXT:END
  171. 1670  IF LO=14 THEN PRINT"WHOOPS! A TRAP DOOR OPENED UNDERNEATH ME AND":PRINT"I FIND MYSELF FALLING.":FOR R=1 TO 4000:NEXT:LO=17:GOTO 110
  172. 1680  PRINT"NOTHING HAPPENED.":GOTO 210
  173. 1690  Z8=0:PRINT"WE ARE PRESENTLY CARRYING:":FOR R=1 TO 46
  174. 1700  IF N(R)<>-1 THEN 1730
  175. 1710  PRINT N1$(R);:IF R=45 AND GL=1 THEN PRINT". WHICH I'M WEARING."ELSE PRINT" "
  176. 1720  Z8=1
  177. 1730  NEXT
  178. 1740  IF Z8=0 THEN PRINT"NOTHING"
  179. 1750  GOTO 210
  180. 1760  IF LO=3 AND N(39)=-1 THEN PRINT"THE DOOR MAN LOOKS AT MY BADGE AND THEN THROWS ME OUT.":FOR R=1 TO 5000:NEXT:LO=1:GOTO 110
  181. 1770  IF LO=10 AND N(42)<>-1 THEN PRINT"THE GUARD LOOKS AT ME SUSPICIOUSLY, THEN THROWS ME BACK.":FOR R=1 TO 4000:NEXT:LO=9:GOTO 110
  182. 1780  IF LO=6 AND BU<>1 THEN PRINT"SIRENS GO OFF ALL AROUND ME!":PRINT"GUARDS RUN IN AND SHOOT ME TO DEATH!":GOTO 2330
  183. 1790  IF LO=11 AND EL<>1 THEN PRINT"THE FLOOR IS WIRED WITH ELECTRICITY!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  184. 1800  IF LO=10 AND N(30)=-1 AND DR=1 THEN PRINT"THE GUARD TAKES MY COFFEE":PRINT"AND FALLS TO SLEEP RIGHT AWAY.":DG=5+RND(10):N(11)=0:N(12)=10:DR=0:N(30)=0:GOTO 240
  185. 1810  IF DG=0 THEN PRINT"I HEAR A NOISE LIKE SOMEONE IS YAWNING.":N(11)=10:N(12)=0:GU=-2:DG=-1:GOTO 240
  186. 1820  IF LO=1 AND N(26)=-1 THEN PRINT"HURRAY! YOU'VE RECOVERED THE RUBY!":PRINT"YOU WIN!":GOTO 2350
  187. 1830  IF T>375 THEN PRINT"I THINK THEY ARE ON TO ME....I HEAR NOISES."
  188. 1840  IF T=400 THEN PRINT"OH NO! THEY CAUGHT UP TO ME! HELP! THEY'RE PULLING OUT GUNS!":GOTO 2330
  189. 1850  IF T=1 THEN PRINT"WRITING ON THE WALL SAYS:":PRINT"IF YOU WANT INSTRUCTIONS TYPE: ORDERS"
  190. 1860  IF LO=6 AND LO(6,2)<>0 THEN PRINT"A SECRET DOOR SLAMS DOWN BEHIND ME!":LO(6,2)=0:GOTO 240
  191. 1870  IF LO=10 AND GU=-2 THEN PRINT"THE GUARD DRAWS HIS GUN AND SHOOTS ME!":GOTO 2330
  192. 1880  GOTO 240
  193. 1890  IF A$="N" THEN A$="GO NORTH":RETURN
  194. 1900  IF A$="S" THEN A$="GO SOUTH":RETURN
  195. 1910  IF A$="E" THEN A$="GO EAST":RETURN
  196. 1920  IF A$="W" THEN A$="GO WEST":RETURN
  197. 1930  IF A$="I" THEN A$="INV":RETURN
  198. 1940  RETURN
  199. 1950  IF V$="WAL" OR V$="RUN" THEN V$="GO ":RETURN
  200. 1960  IF V$="TAK" OR V$="CAR" THEN V$="GET":RETURN
  201. 1970  IF V$="LEA" THEN V$="DRO":RETURN
  202. 1980  IF V$="PRE" THEN V$="PUS":RETURN
  203. 1990  IF V$="EXA" THEN V$="LOO":RETURN
  204. 2000  IF V$="PUT" THEN V$="INS":RETURN
  205. 2010  IF V$="UNL" THEN V$="OPE":RETURN
  206. 2020  IF V$="PLA" THEN V$="STA":RETURN
  207. 2030  IF V$="SMA" THEN V$="BRE":RETURN
  208. 2040  IF V$="ATT" THEN V$="CON":RETURN
  209. 2050  IF V$="LIS" THEN V$="INV":RETURN
  210. 2060  RETURN
  211. 2070  DATA A VIDEO CASSETTE RECORDER,REC,2,A VIDEO TAPE,TAP,0,A LARGE BATTERY,BAT,0,A BLANK CREDIT CARD,CAR,0
  212. 2075  DATA AN ELECTRONIC LOCK,LOC,0,AN ELABORATE PAPER WEIGHT,WEI,5,A LOCKED WOODEN DOOR,DOO,4,AN OPEN WOODEN DOOR,DOO,0,A SOLID LOOKING DOOR,DOO,10
  213. 2080  DATA AN OPEN DOOR,DOO,0,AN ALERT SECURITY GUARD,GUA,10,A SLEEPING SECURITY GUARD,GUA,0,A LOCKED MAINTENANCE CLOSET,CLO,14
  214. 2085  DATA A MAINTENANCE CLOSET,CLO,0,A PLASTIC BAG,BAG,13,AN OLDE FASHIONED KEY,KEY,9,A SMALL METAL SQUARE ON THE WALL,SQU,16
  215. 2090  DATA A LEVER ON THE SQUARE,LEV,16,AN OLD MAHOGANY DESK,DES,5,A BROOM,BRO,13,A DUSTPAN,DUS,13,A SPIRAL NOTEBOOK,NOT,0
  216. 2095  DATA A MAHOGANY DRAWER,DRA,0,A GLASS CASE ON A PEDESTAL,CAS,6,A RAZOR BLADE,BLA,27,A VERY LARGE RUBY,RUB,0,A SIGN ON THE SQUARE
  217. 2100  DATA SIG,16,A QUARTER,QUA,0,A COFFEE MACHINE,MAC,8,A CUP OF STEAMING HOT COFFEE,CUP,0,A SMALL CAPSULE,CAP,0,A LARGE SCULPTURE,SCU,3
  218. 2105  DATA A TALL OFFICE BUILDING,BUI,1,A PAIR OF SLIDING DOORS,DOO,3,A LARGE BUTTON ON THE WALL
  219. 2110  DATA BUT,29,A PANEL OF BUTTONS NUMBERED ONE THRU THREE,PAN,9,A STRONG NYLON ROPE,ROP,17
  220. 2115  DATA A LARGE HOOK WITH A ROPE HANGING FROM IT,HOO,21,A C.I.A. IDENTIFICATION BADGE,BAD,-1,A PORTABLE TELEVISION,TEL,7
  221. 2120  DATA A BANK OF MONITORS,MON,7,A CHAOS I.D. CARD
  222. 2130  DATA CAR,30,A BANK OF MONITORS,MON,19,A SMALL PAINTING,PAI,23,A PAIR OF RUBBER GLOVES,GLO,13,A BOX WITH A BUTTON ON IT,BOX,24
  223. 2135  DATA ONE,ONE,9,TWO,TWO,9,THREE,THR,9,SLIT,SLI,10,ON A BUSY STREET,0,0,0,0,IN A VISITOR'S ROOM,0,0,3,0
  224. 2140  DATA IN THE LOBBY OF THE BUILDING,1,0,4,2,IN A DINGY ANTE ROOM,0,0,0,3
  225. 2150  DATA IN THE COMPANY PRESIDENT'S OFFICE,0,0,0,4,IN A SMALL SOUND PROOFED CUBICLE,0,12,0,0,IN A SECURITY OFFICE,0,0,8,0
  226. 2155  DATA IN A SMALL HALLWAY,14,9,0,7,IN A SMALL ROOM,3,0,0,0,IN A SHORT CORRIDOR,0,9,15,0,IN A HALLWAY MADE OF METAL,0,10,12,0
  227. 2160  DATA IN A SMALL PLAIN ROOM,6,0,0,11
  228. 2170  DATA IN A MAINTENANCE CLOSET,0,0,14,0,IN A CAFETERIA,0,8,0,0,IN A SIDE CORRIDOR,0,0,16,10,IN A POWER GENERATOR ROOM,0,0,0,15,IN A SUB-BASEMENT BELOW THE CHUTE,0,0,18,0,IN THE ENTRANCE TO THE SECRET COMPLEX,0,20,19,17
  229. 2180  DATA IN A SECRET MONITORING ROOM,0,0,0,18,ON A LEDGE IN FRONT OF A METAL PIT 1000'S OF FEET DEEP,18,0,0,0,ON THE OTHER SIDE OF THE PIT,0,0,22,0,IN A LONG CORRIDOR,0,25,23,21,IN A LARGE ROOM,0,26,0,22,IN A SECRET LABORATORY,0,0,25,0
  230. 2190  DATA IN A NARROW CROSS CORRIDOR,22,0,0,24,IN A CROSS EXAMINATION ROOM,23,28,0,0,IN A SMALL BATHROOM,0,0,28,0,IN THE OFFICE OF THE CHIEF OF CHAOS,26,30,0,27,IN THE CHAOS CONTROL ROOM,0,0,30,0,NEAR THE END OF THE COMPLEX,28,0,0,29
  231. 2200  DATA "GO ",GET,DRO,PUS,PUL,LOO,INS,OPE,WEA,REA,STA,BRE,CUT,THR,CON,QUI,BON,INV
  232. 2210  PRINT"YOUR MISSION, ";NA$;",":PRINT"IS TO RECOVER A RUBY THAT IS BEING";
  233. 2220  PRINT" USED IN TOP SECRET GOVERNMENT PROJECTS AS A PART IN A";
  234. 2230  PRINT" LASER PROJECTOR.";
  235. 2240  PRINT"  YOUR COMPUTER WILL BE YOUR PARTNER AND";
  236. 2250  PRINT" YOU WILL HAVE TO TELL IT WHAT TO DO.":PRINT" USE TWO WORD COMMANDS LIKE:"
  237. 2260  PRINT:PRINT"              GET NOTEBOOK   GO WEST   LOCK DOOR"
  238. 2270  PRINT:PRINT"SOME COMMANDS USE ONLY ONE WORD. FOR EXAMPLE: INVENTORY"
  239. 2280  PRINT"  IF YOU WANT TO SEE CHANGES IN YOUR SURROUNDINGS TYPE: LOOK"
  240. 2290  PRINT"THE RUBY HAS BEEN CAPTURED BY A SECRET SPY RING KNOWN AS";
  241. 2300  PRINT" CHAOS. WE SUSPECT THEY ARE UNDER COVER SOMEWHERE IN THIS"
  242. 2310  PRINT"NEIGHBORHOOD. GOOD LUCK!"
  243. 2320  GOTO 240
  244. 2330  FOR R=1 TO 5000:NEXT:PRINT"I'M DEAD!"
  245. 2340  PRINT"YOU DIDN'T WIN."
  246. 2350  INPUT"WOULD YOU LIKE TO TRY AGAIN (Y/N)";Z$
  247. 2360  IF Z$="Y" THEN RUN
  248. 2365  IF Z$="N" THEN END
  249. 30000  'LOW2UP by Carl Berger 9/21/85 rev.4:06pm<UNK! {000A}> Routine to convert lowercase  to UPPERCASE
  250. 30010  L9=LEN(A$)
  251. 30020  FOR C9=1 TO L9:CK$=MID$(A$,C9,1)
  252. 30030  IF CK$=""THEN 30060
  253. 30040  K9=ASC(CK$)
  254. 30050  IF K9>96 AND K9<123 THEN CK$=CHR$(K9-32):MID$(A$,C9,1)=CK$
  255. 30060  NEXT C9
  256. 30070  RETURN
  257. 30080  ' ** Last line of LOW2UP/BAS ** and CIA/BAS **
  258.